mayaの起動バッチ改

 以前にも mayaを起動するバッチを紹介していますが、mayaが LTだったり公開したのが2015年と、かなり情報が古い感じがしたので、今作るなら、こんな風な maya起動用.batファイルになるのかなぁというのを改めて。

 今回は maya2026を起動するようなバッチファイルにしてみます。

@echo off
title %0

set VERSION=2026

set MAYA_BIN_PATH=C:\Program Files\Autodesk\Maya%VERSION%\bin
if not exist "%MAYA_BIN_PATH%" goto :errMAYA


::------------------------------------------------------------------------------
:: 環境変数設定
::------------------------------------------------------------------------------
:: 言語モード
if "1"=="%1" set MAYA_UI_LANGUAGE=en_US
if not "1"=="%1" set SUF=JP
:: スクリプトパス
set MAYA_SCRIPT_PATH=%~dp0scripts
:: set PYTHONPATH=%~dp0scripts
:: プラグインパス
:: set MAYA_PLUG_IN_PATH=%~dp0plug-ins
:: 終了時 STDIN 確認モードをスキップ
set MAYA_SKIP_BLOCK_CHECK=1
:: arnoldの警告非表示
set MAYA_NO_WARNING_FOR_MISSING_DEFAULT_RENDERER=1

:: プロジェクトメニューを表示させる環境変数※userSetup.melで使用
set MAYA_PROJECT=1
:: プロジェクトパスの環境変数※StartUp.melで使用
set MAYA_PROJECT_PATH=%~dp0


if not "1"=="%2" goto :skipSaveLog
::------------------------------------------------------------------------------
:: ログ用の日付を作成
set YYYYMMDD=%date%
set YYYYMMDD=%YYYYMMDD:/=%
set HHMMSS=%TIME%
set HHMMSS=%HHMMSS:~0,5%
set HHMMSS=%HHMMSS::=%
set HHMMSS=%HHMMSS: =0%
:: ログの出力設定
set MAYA_LOG_PATH=%~dp0_mayaCommandLog
if not exist %MAYA_LOG_PATH% md %MAYA_LOG_PATH%
set MAYA_CMD_FILE_OUTPUT=%MAYA_LOG_PATH%\mayaCommand_%YYYYMMDD%_%HHMMSS%%SUF%.log
::------------------------------------------------------------------------------
:skipSaveLog


::------------------------------------------------------------------------------
:: maya起動
echo STARTING MAYA %VERSION%
start "starting maya" "%MAYA_BIN_PATH%\maya.exe" -hideConsole
timeout /t 30
goto :EOF



::------------------------------------------------------------------------------
:errMAYA
    echo ## 指定のパスが存在しません。##
    echo "%MAYA_BIN_PATH%"
    pause

 独自の pythonスクリプトやプラグインが有る場合には、18行目や20行目のコメントアウトを解除します。

このバッチファイルのショートカットを作成して、プロパティからリンク先の.batの後ろに0以外を付ける事で英語起動とログ出力が出来るようになります。

 0 1 日本語版・ログ出力
 1   英語版・ログ無し
のような感じです。上のプロパティでは英語版・ログ出力になっています。

 そして、基本的に４行目のバージョン番号を変えることで、簡単に起動する mayaのバージョンを指定できます。 たとえば、

set VERSION=Creative2026

とすることで Maya Creative用のバッチになります。
 複数インストールしている場合、簡単に切り替えが出来てしまう割に Flexの消費コストがまるっきり違うので間違えないように気を付けたいところです。

 この部分も引数やファイル名などからバージョン情報を取るとかすれば、管理するのは１つのバッチファイルだけで済むから便利なようにも思いますが、プロジェクトメンバー全員が確実に同じバージョンの mayaが起動しているかが担保できなくなるので、個人的に使う場合だけに限定した方が良いのかもしれませんね。