mayaのswatchesフォルダを除去する

  mayaでファイルを開きテクスチャを表示させるなどすると開いた画像と同じパスに .mayaSwatches というフォルダが作成されます。

  たまに隠し属性になっていたりするので、気にならない人も居るようですが、ファイルの受け渡しなんかで見つけるとゴミを含んでいるようで、なんだかスッキリしません。

  ブログへ上げたような気もしたのですが見つからなかったので改めて。

  今回はバッチファイルで対処します。さっそくコードを

@set BAT=%~n0
@prompt %BAT%$G

@set DROP_PATH="%~dpn1"
@title %BAT% %DROP_PATH%


:: 実行した日時
@set YYYYMMDD=%DATE:/=%
@set HHMMSS=%TIME:~0,-3%
@set HHMMSS=%HHMMSS::=%
@set HHMMSS=%HHMMSS: =0%


:: 削除用バッチファイル作成
@set FILE_NAME=rdMayaSwatches
@set BAT_FILE=%USERPROFILE%\desktop\%FILE_NAME%_%YYYYMMDD%_%HHMMSS%.bat

@echo @prompt %FILE_NAME%$G>>%BAT_FILE%
@echo @title %FILE_NAME%.bat>>%BAT_FILE%
@echo.>>%BAT_FILE%


:: mayaSwatchesフォルダの検索
@cd /D %DROP_PATH%
@for /F "delims=," %%I in ('dir *mayaSwatches /A:D /B /S') do echo rd /S /Q "%%I">>%BAT_FILE%
@echo @pause>>%BAT_FILE%

pause

  これを deleteMayaSwatch.bat みたいなファイル名を付けて保存します。

  このバッチファイルはどこへ保存しても良いのですがデスクトップにでも置いておくと良いかと思います。

  そして、mayaSwatchesフォルダの在りそうなフォルダをこのバッチファイルへドラッグアンドドロップします。

  そうすると、DOS窓が開き、デスクトップに rdMayaSwatches_実行日時.bat のようなバッチファイルが作成されます。
  この rdMayaSwatches_実行日時.bat をダブルクリックすることで DOS窓が開き .mayaSwatchesフォルダが削除されます。
  実行前にテキストエディタで確認すれば、どんなパスに .mayaSwatchesフォルダがあるのかを確認できます。

  けれども、SVNでバージョン管理の対象になっている.mayaSwatchesフォルダなんかは「更新」のたびに復活してしまうので、SVNのコンテキストメニューから「削除」してコミットする必要があります。

  そもそも管理対象から外しておくべきなんですけど、忘れがち。